Manipulera samlingar

Du tappade åtminstone en tabelldefinition i det andra fallet. Detta uttalande:

create or replace TYPE tbl_list2 IS OBJECT (l_owner  VARCHAR2(64),l_name  VARCHAR2(64));

deklarerar endast objekt (eller post) typ, inte en tabell.

Så du måste göra det i två steg:

create or replace TYPE tbl_list_rec IS OBJECT (l_owner  VARCHAR2(64),l_name  VARCHAR2(64));
/

create or replace TYPE tbl_list2 as table of tbl_list_rec;
/

Efter det behöver du några syntaxkorrigeringar i skriptet:

declare
  l_object tbl_list2;
  i        number;
begin
  -- for list initialization it must be filled with constructed objects
  l_object := tbl_list2( tbl_list_rec('','') );

  for i in 1..100000 loop          

    -- 1. select values to variable
    -- 2. Fix constructor for list 
    select 
      l_object MULTISET UNION DISTINCT tbl_list2(tbl_list_rec('myOwner','MyTable'))
    into 
      l_object 
    from 
      dual;

    end loop;

    for i in l_object.first ..  l_object.last loop
      -- output separate fields, there are now default conversion from 
      -- user-defined objects to varchar2.
      dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
    end loop;  

end;
/

UPPDATERA

Lösningen ovan relativt långsam på grund av stort antal kontextväxlar. Men jämförelse av komplexa objekttypsinstanser kan inte göras direkt i PL/SQL utan extra arbete.
För att Oracle ska kunna veta om objektinstanser är samma eller olika måste vi definiera mappnings- eller beställningsmetod för objekttyp . Båda typerna av metoder är inte tillåtna, så det är nödvändigt att välja rätt. MAP-metoder fungerar snabbare och det finns inget behov av att beställa i vårt fall, så kör för det:

create or replace TYPE tbl_list_rec2 AS OBJECT (
  l_owner  VARCHAR2(64),
  l_name  VARCHAR2(64),
  map member function get_key return varchar2
);
/

Implementering:

create or replace TYPE BODY tbl_list_rec2 AS 

  map member function get_key return varchar2
  is
  begin
    return l_owner||chr(1)||l_name;
  end;

end;
/

Efter det är det möjligt att testa objekt för likhet i PL/SQL-kod som enkel varchar2 i första exemplet från fråga:

declare
  l_object tbl_list2a;
  i        number; 
begin
  l_object := tbl_list2a( tbl_list_rec2('','') );

  for i in 1..100000 loop          
    l_object := l_object MULTISET UNION DISTINCT tbl_list2a(tbl_list_rec2('myOwner','MyTable'));
  end loop;

  for i in l_object.first..  l_object.last loop
    dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
  end loop;  

end;
/