Perl och XPath:saknade poster i databastabellen

Du har redan en förklaring och en korrigering, men jag föreslår följande ändringar

• Du bör prepare INSERT INTO SQL-sats och sedan execute det inom slingan. do har en mycket större omkostnad

• // ( descendant-or-self::node() ) XPath-konstruktionen är dyr och du bör reservera den för fall där du inte har någon aning om var elementet kommer att finnas i dokumentet, vilket är mycket sällsynt. I det här fallet row1 element finns på /database/row1s/row1 och row2 element finns vid row2s/row2 i förhållande till det

• Det är mycket renare att använda olika avgränsare om du vill använda citattecken inom en citattecken. Till exempel "My name is \"$name\"" är mycket bättre som qq{My name is "$name"}

Här är en version av ditt program som kan hjälpa dig.

use strict;
use warnings;

use XML::XPath;
use DBI;

my $xp = XML::XPath->new( filename => 'animals4.xml' );

my $dbh = DBI->connect(
   'DBI:mysql:test', 'user', 'pw',
   { RaiseError => 1, PrintError => 0}
) or die "Fehler beim Verbidungsaufbau zum MariaDB-Server: $DBI::err -< $DBI::errstr\n";

my $insert_animal = $dbh->prepare('INSERT INTO animal4 (name, category, type, size) VALUES (?, ?, ?, ?)');

for my $row1 ( $xp->findnodes('/database/row1s/row1') ) {

   my $name     = $row1->getAttribute('name');
   my $category = $row1->getAttribute('category');

   printf qq{Level --- row1 "name" gives: $name\n};

   my @row2 = $xp->findnodes('row2s/row2', $row1);

   if ( @row2 ) {
      for my $row2 ( @row2 ) {

         my $type = $row2->getAttribute('type');
         my $size = $row2->getAttribute('size');

         print qq{Level row2 "type" gives: $type\n};
         print qq{Level row2 "size" gives: $size\n};

         $insert_animal->execute($name, $category, $type, $size);
      }
   }
   else {
      $insert_animal->execute($name, $category, undef, undef);
   }
}

utgång

Level --- row1 "name" gives: fox
Level row2 "type" gives: 1
Level row2 "size" gives: 10
Level row2 "type" gives: 2
Level row2 "size" gives: 8
Level --- row1 "name" gives: horse
Level row2 "type" gives: 3
Level row2 "size" gives: 100
Level --- row1 "name" gives: bee
Level --- row1 "name" gives: wasp