Tabellfunktion med massinsamling kastar ogiltig datatyp

Du försöker använda paketnivåtyper i vanlig SQL, vilket inte är tillåtet. Typerna som deklareras i paketet är inte synliga för eller giltiga utanför PL/SQL (eller ens i vanliga SQL-satser inom PL/SQL). En förkortad version av vad du gör:

create or replace package types as
    type my_rec_type is record (dummy dual.dummy%type);
    type my_table_type is table of my_rec_type index by binary_integer;
end types;
/

create or replace package p42 as
    function get_table return types.my_table_type;
end p42;
/

create or replace package body p42 as
    function get_table return types.my_table_type is
        my_table types.my_table_type;
    begin
        select * bulk collect into my_table from dual;
        return my_table;
    end get_table;
end p42;
/

select * from table(p42.get_table);

SQL Error: ORA-00902: invalid datatype

Även inom paketet, om du hade en procedur som försökte använda tabellfunktionen skulle det fel. Om du har lagt till:

    procedure test_proc is
    begin
        for r in (select * from table(get_table)) loop
            null;
        end loop;
    end test_proc;

... paketets kroppskompilering skulle misslyckas med ORA-22905: cannot access rows from a non-nested table item .

Du måste deklarera typerna på schemanivå, inte i ett paket, så använd SQL create type kommando :

create type my_obj_type is object (dummy varchar2(1));
/

create type my_table_type is table of my_obj_type;
/

create or replace package p42 as
    function get_table return my_table_type;
end p42;
/

create or replace package body p42 as
    function get_table return my_table_type is
        my_table my_table_type;
    begin
        select my_obj_type(dummy) bulk collect into my_table from dual;
        return my_table;
    end get_table;
end p42;
/

select * from table(p42.get_table);

DUMMY
-----
X