Groovy Oracle Stored Proc - ogiltigt kolumnindex

Följande kod kan hjälpa dig att få variabeln SYS_REFCURSOR från Oracles anonyma block.

Vi bör fokusera på några viktiga detaljer:

1. Klass groovy.sql.Sql har inte motsvarande OutParameter och vi gör det manuellt som CURSOR_PARAMETER och skicka den till sql.call metod
2. Tänk på att blocket börjar med {call DECLARE och slutar med END } utan semikolon efter END. Annars kan vi få en dåligt igenkännlig SQLException i ansiktet.
3. Frågetecknen ? inuti sqlString är platser för parameterbindningar. Bindningar görs i naturlig ordning med värden från parametersList .
   • I det här exemplet har vi den enda bindningen, så ? binder med CURSOR_PARAMETER som behandlar värdet som OUT parameter av godkänd typ;
4. Det finns bara en stängning efter sql.call och ResultSet rs tillhandahålla rader med markör my_cur deklareras i anonymt block.
5. Vi kan förenkla sqlString genom att använda en funktion som returnerar SYS_REFCURSOR istället för en procedur med OUT parameter. Så det kan se ut så här "{call BEGIN ? := MY_FUNC(); END}" eller till och med "{? = call MY_FUNC()}"

import groovy.sql.OutParameter
import groovy.sql.Sql
import oracle.jdbc.OracleTypes

import java.sql.ResultSet

def driver = 'oracle.jdbc.driver.OracleDriver'
def sql = Sql.newInstance('jdbc:oracle:thin:@my-server:1521:XXX', 'usr', 'psw', driver)

// special OutParameter for cursor type
OutParameter CURSOR_PARAMETER = new OutParameter() {
    public int getType() {
        return OracleTypes.CURSOR;
    }
};

// look at some ceremonial wrappers around anonymous block
String sqlString = """{call
    DECLARE
      my_cur SYS_REFCURSOR;
    BEGIN
        STORED_PROCEDURE_NAME(my_cur);
        ? := my_cur;
    END
}
""";

// the order of elements matches the order of bindings
def parametersList = [CURSOR_PARAMETER];


// rs contains the result set of cursor my_cur
sql.call(sqlString, parametersList) { ResultSet rs ->
  while (rs.next()) {
      println rs.getString("my_column")
  }
};

P.S. Och tack för frågan.