hitta kolumnnamn och tabellnamn som refereras till i SQL

Jag har en bra lösning för dig, men det finns två saker du behöver göra:

Placera SQL inuti en PL/SQL-programenhet. Så, ja, till den lagrade proceduren du nämnde.
Kompilera den programenheten och alla beroende tabeller (det vill säga installera din applikationskod) på en 12.2-instans (du kan ladda ner 12.2 på http://www.oracle.com/technetwork/database/enterprise-edition/downloads/index.html eller så kan du köpa en Exadata Express Cloud Service på cloud.oracle.com eller få en kredit på 300 USD för att använda en utan kostnad i en månad på cloud.oracle.com/tryit).

12.2 är nyckeln eftersom funktionen du VERKLIGEN vill använda kallas PL/Scope och det är ett kompilatorverktyg som samlar information om PL/SQL-identifierare (från 11.1) och SQL-användning i PL/'SQL (från 12.2).

CREATE TABLE my_data (n NUMBER)
/

ALTER SESSION SET plscope_settings='identifiers:all, statements:all'
/

CREATE OR REPLACE PROCEDURE my_procedure (n_in IN NUMBER)
   AUTHID DEFINER
IS
   l_n           my_data.n%TYPE;

   CURSOR all_data_cur
   IS
          SELECT *
            FROM my_data
      FOR UPDATE OF n;
BEGIN
   INSERT INTO my_data (n)
        VALUES (n_in);

END;
/

  SELECT idt.line,
         idt.owner || '.' || idt.object_name code_unit, 
         idt.name column_name,
         RTRIM (src.text, CHR (10)) text
    FROM all_identifiers idt, all_source src
   WHERE     idt.usage = 'REFERENCE'
         AND idt.TYPE = 'COLUMN'
         AND idt.line = src.line
         AND idt.object_name = src.name
         AND idt.owner = src.owner
         AND idt.object_name = 'MY_PROCEDURE'
ORDER BY code_unit, line
/

LINE CODE_UNIT          COLUMN_NAME TEXT  
4   STEVEN.MY_PROCEDURE N           l_n           my_data.n%TYPE;
10  STEVEN.MY_PROCEDURE N           FOR UPDATE OF n;
12  STEVEN.MY_PROCEDURE N           INSERT INTO my_data (n)

Hoppas det hjälper!

Många fler exempel på PL/Scope på livesql.oracle.com. Sök bara efter "pl/omfattning" (duh).