Hur sparar jag BLOB som fil i PL/SQL?

Här ger jag ett exempel för att spara BLOB-data som en fil i PL/SQL. BLOB-data kan du hämta det från tabellen med BLOB-kolumnen, eller så kan du hämta det från en fil på disken.

PL/SQL-funktionsexempel för att spara BLOB som en fil

Proceduren nedan tar följande tre argument:

1. Oracle Directory Objektnamn (som i_dir).
2. Spara som filnamn (som i_fil).
3. BLOB-data (som i_blob).

CREATE OR REPLACE PROCEDURE blob_to_file (i_dir    IN VARCHAR2,
                                          i_file   IN VARCHAR2,
                                          i_blob   IN BLOB)
AS
   l_file       UTL_FILE.file_type;
   l_buffer     RAW (32767);
   l_amount     BINARY_INTEGER := 32767;
   l_pos        INTEGER := 1;
   l_blob_len   INTEGER;
BEGIN
   l_blob_len := DBMS_LOB.getlength (i_blob);

   l_file :=
      UTL_FILE.fopen (i_dir,
                      i_file,
                      'WB',
                      32767);

   WHILE l_pos < l_blob_len
   LOOP
      DBMS_LOB.read (i_blob,
                     l_amount,
                     l_pos,
                     l_buffer);
      UTL_FILE.put_raw (l_file, l_buffer, TRUE);
      l_pos := l_pos + l_amount;
   END LOOP;

   UTL_FILE.fclose (l_file);
EXCEPTION
   WHEN OTHERS
   THEN
      IF UTL_FILE.is_open (l_file)
      THEN
         UTL_FILE.fclose (l_file);
      END IF;

      RAISE;
END blob_to_file;

Testa

Följande PL/SQL-block kommer att anropa proceduren ovan genom att skicka Oracle-katalogobjektet, filnamnet och BLOB-data. För BLOB-data använder jag funktionen GET_BLOB som jag har gett ett exempel på i mitt tidigare blogginlägg:Hämta BLOB från en fil i PL/SQL. I fallet nedan kommer den att hämta BLOB-data från en fil myfile.jpg från MY_DIR-platsen och spara den till filen abc.jpg på IMG_DIR-platsen.

DECLARE
   f_blob   BLOB;
BEGIN
   /* check the above mentioned link for get_blob function example */
   f_blob := get_blob ('MY_DIR', 'myfile.jpg');
   /* now pass the blob to blob_to_file procedure to save it as a file */
   blob_to_file ('IMG_DIR', 'abc.jpg', f_blob);
END;

Nu kan du kontrollera platsen för IMG_DIR-katalogen för filen som skapats via BLOB.

Se även:

• Hur skapar man ett Oracle Directory-objekt?
• Lär dig hur du extraherar BLOB-data från Oracle Table med hjälp av Toad