Hur kontrollerar jag om filen är en bild som använder PL/SQL?

I det här blogginlägget delar jag en funktion som du kan kontrollera om en fil är en bildfil eller inte använder PL/SQL. Programmet kommer att kontrollera filen genom att läsa dess rubrik, inte filtilläggsnamnet. För närvarande kan funktionen identifiera tre typer av bilder som är JPG, PNG och GIF.

PL/SQL-funktion för att kontrollera om filen är en bildfil

Följande PL/SQL-funktion läser filhuvudet och returnerar sedan bildtypen i datatypen varchar2. Funktionen get_image_type tar två argument och de är följande:

1. Oracle Directory Object (som i_dir) Lär dig hur du skapar Oracle Directory Object.
2. Filnamn (som i_file) fil bör finnas i katalogen.

CREATE OR REPLACE FUNCTION get_image_type (i_dir    IN VARCHAR2,
                                           i_file   IN VARCHAR2)
   RETURN VARCHAR2
AS
   l_bfile       BFILE;
   l_blob        BLOB;
   l_file_type   VARCHAR2 (50);
BEGIN
   DBMS_LOB.createtemporary (l_blob, FALSE);
   l_bfile := BFILENAME (i_dir, i_file);
   DBMS_LOB.fileopen (l_bfile, DBMS_LOB.file_readonly);
   DBMS_LOB.loadfromfile (l_blob, l_bfile, DBMS_LOB.getlength (l_bfile));
   DBMS_LOB.fileclose (l_bfile);

   IF RAWTOHEX (DBMS_LOB.SUBSTR (l_blob, 8, 1)) = '89504E470D0A1A0A'
   THEN
      l_file_type := 'PNG';
   ELSIF DBMS_LOB.SUBSTR (l_blob, 3, 1) = '474946'
   THEN
      l_file_type := 'GIF';
   ELSIF RAWTOHEX (DBMS_LOB.SUBSTR (l_blob, 3, 1)) = 'FFD8FF'
   THEN
      l_file_type := 'JPG';
   ELSE
      l_file_type := 'The file is not an image.';
   END IF;

   RETURN l_file_type;
EXCEPTION
   WHEN OTHERS
   THEN
      IF DBMS_LOB.fileisopen (l_bfile) = 1
      THEN
         DBMS_LOB.fileclose (l_bfile);
      END IF;

      DBMS_LOB.freetemporary (l_blob);
      RETURN 'The file does not exists.';
END get_image_type;

Testa

I nedanstående PL/SQL-program, ändra MY_FILES Oracle-katalogobjekt med ditt katalogobjekt och ändra filnamnet med filen som är tillgänglig i MY_FILES katalogplats.

SET SERVEROUTPUT ON;

DECLARE
   i_image_type   VARCHAR2 (50);
BEGIN
   i_image_type := get_image_type ('MY_FILES', 'oracle-logo-gif-to-use.gif');

   IF i_image_type IN ('JPG', 'GIF', 'PNG')
   THEN
      DBMS_OUTPUT.put_line ('The file is a valid ' || i_image_type || ' image.');
   ELSE
      DBMS_OUTPUT.put_line (i_image_type);
   END IF;
END;
/

Utdata

The file is a valid GIF image.
PL/SQL procedure successfully completed.

Se även:

• Hur infogar man en fil i Oracle Table med PL/SQL?