4 PL/SQL anonyma blockexempel

I den här handledningen ger jag 4 PL/SQL anonyma blockexempel, så att du kan lära dig hur du skapar och använder anonyma block i Oracle-databasen. Anonyma block i PL/SQL är de program som inte har någon Create Procedure eller Create Function-sats, och som inte sparas i Oracle-databasen. PL/SQL anonyma block används oftast för att testa eller för att köra programmet i Oracle-databasen endast en gång.

1. PL/SQL anonymt block för att skriva ut nummer i omvänd ordning

Följande PL/SQL-program kommer att skriva ut siffrorna 0 till 10 i omvänd ordning, med REVERSE-sats i för loop.

SET SERVEROUTPUT ON;
DECLARE
  counter   NUMBER;
BEGIN
  FOR counter IN REVERSE 0..10 LOOP
    DBMS_OUTPUT.PUT_LINE (counter);
  END LOOP;
END;
/

Utdata

10
9
8
7
6
5
4
3
2
1
0
PL/SQL procedure successfully completed.

2. Skriv ut Antal anställda i en avdelning

Följande PL/SQL-program kommer att räkna medarbetarna på avdelning 90. Tabellen är från HR-schemat i Oracle-databasen. Du kan ladda ner detta schema från följande länk Ladda ner HR Schema.

SET SERVEROUTPUT ON;

DECLARE
   emp_count         NUMBER;
   v_department_id   NUMBER := 90;
BEGIN
   SELECT COUNT ( * )
     INTO emp_count
     FROM employees
    WHERE department_id = v_department_id;

   DBMS_OUTPUT.PUT_LINE(   'The employee count is: '
                        || emp_count
                        || ' for the department with an ID of: '
                        || v_department_id);
END;
/

Utdata

The employee count is: 3 for the department with an ID of: 90
PL/SQL procedure successfully completed.

3. Ta indata i PL/SQL anonym blockering och skriv ut

I exemplet nedan kommer den att be om indata från användaren för avdelnings-ID och kommer att skriva ut antalet anställda i den avdelningen, och även skriva ut avdelningsnamnet.

SET SERVEROUTPUT ON;

DECLARE
   dept_id_var   NUMBER (4) := &department_id;
   dept_name     VARCHAR2 (30);
   emp_count     NUMBER;
BEGIN
   SELECT COUNT ( * )
     INTO emp_count
     FROM employees
    WHERE department_id = dept_id_var;

   SELECT department_name
     INTO dept_name
     FROM departments
    WHERE department_id = dept_id_var;

   DBMS_OUTPUT.PUT_LINE(   'There are '
                        || emp_count
                        || ' employees '
                        || 'in the '
                        || dept_name
                        || ' department.');
END;
/

Utdata

Enter value for department_id: 60
old   2:   dept_id_var  NUMBER(4) := &department_id;
new   2:   dept_id_var  NUMBER(4) := 60;
There are 4 employees in the IT department.

PL/SQL procedure successfully completed.

4. PL/SQL-block med <> Exempel

Följande PL/SQL-block använder etiketterna för överordnat och underordnat block. Det underordnade blocket kommer åt föräldrablockets variabel genom att använda etikettreferensen för det överordnade blocket. Programmet kommer att uppdatera det gamla chefs-ID med nytt chefs-ID för avdelningarna.

SET SERVEROUTPUT ON;
<<outer_block>>
DECLARE
   mgr_id       NUMBER (6) := '&current_manager_id';
   dept_count   NUMBER := 0;
BEGIN
   SELECT COUNT ( * )
     INTO dept_count
     FROM departments
    WHERE manager_id = outer_block.mgr_id;

   IF dept_count > 0
   THEN
     <<inner_block>>
      DECLARE
         dept_name   VARCHAR2 (30);
         mgr_id      NUMBER (6) := '&new_manager_id';
      BEGIN
         SELECT department_name
           INTO dept_name
           FROM departments
          WHERE manager_id = outer_block.mgr_id;

         UPDATE departments
            SET manager_id = inner_block.mgr_id
          WHERE manager_id = outer_block.mgr_id;

         DBMS_OUTPUT.PUT_LINE (
            'Department manager ID has been changed for ' || dept_name);
      END inner_block;
   ELSE
      DBMS_OUTPUT.PUT_LINE (
         'There are no departments listed for the manager');
   END IF;
EXCEPTION
   WHEN NO_DATA_FOUND
   THEN
      DBMS_OUTPUT.PUT_LINE (
         'There are no departments listed for the manager');
END outer_block;
/

Utdata

Enter value for current_manager_id: 100
old 3: mgr_id NUMBER (6) := '&current_manager_id';
new 3: mgr_id NUMBER (6) := '100';
Enter value for new_manager_id: 201
old 16: mgr_id NUMBER (6) := '&new_manager_id';
new 16: mgr_id NUMBER (6) := '201';
Department manager ID has been changed for Executive

PL/SQL procedure successfully completed.