Hur validerar man kreditkortsnummer och identifierar dess typ med PL/SQL?

Här ger jag ett exempel på PL/SQL lagrad funktion för att validera kreditkortsnumret och identifiera dess typ, oavsett om det är ett Visa, MasterCard eller American Express kreditkort. Jag kontrollerar kreditkortsnumret med hjälp av LUHN-algoritmen som används för att validera en mängd olika identifikationsnummer. Om kreditkortsnumret är giltigt, kontrollerar funktionen efter dess typ.

PL/SQL-funktionsexempel för att validera kreditkortsnummer och dess typ i Oracle

Följande funktion tar ett argument som kreditkortsnummer och validerar sedan numret med Luhns algoritm och returnerar dess typ. För närvarande stöder denna PL/SQL-funktion tre typer av kreditkort som är Visa, MasterCard och American Express. Du kan ändra för att lägga till fler kreditkortstyper. Funktionen CHECK_LUHN_ALGO för att kontrollera numret med hjälp av Luhns algoritm skrivs inuti funktionen VALIDATE_CC, så om du vill lägga till fler korttypers stöd behöver du inte ändra CHECK_LUHN_ALGO-funktionen, ändra bara huvuddelen av funktionen VALIDATE_CC.

CREATE OR REPLACE FUNCTION validate_CC (cc_number IN VARCHAR2)
   RETURN VARCHAR2
IS
   v_ret_string   VARCHAR2 (100);

   FUNCTION check_luhn_algo (p_ccnumber VARCHAR2)
      RETURN NUMBER
   IS
      i          NUMBER;
      n_ntoi     SMALLINT;
      n_retval   SMALLINT;
      n_calc     NUMBER := 0;
      n_ntoc     NUMBER;
   BEGIN
      n_ntoc := LENGTH (p_ccnumber);

      FOR i IN 1 .. n_ntoc
      LOOP
         n_ntoi := TO_NUMBER (SUBSTR (p_ccnumber, n_ntoc + 1 - i, 1));

         n_calc :=
              n_calc
            + MOD (i, 2) * n_ntoi
            + MOD (i + 1, 2) * SIGN (-SIGN (n_ntoi - 4) + 1) * (2 * n_ntoi)
            +   MOD (i + 1, 2)
              * SIGN (SIGN (n_ntoi - 5) + 1)
              * (2 * n_ntoi - 9);
      END LOOP;

      n_retval := SIGN (MOD (n_calc, 10));

      RETURN n_retval;
   EXCEPTION
      WHEN OTHERS
      THEN
         RETURN 1;
   END check_luhn_algo;
BEGIN
   /* Credit card number is invalid if below funciton returns non zero value */
   IF check_luhn_algo (cc_number) != 0
   THEN
      v_ret_string := 'Not a valid Credit Card Number.';
      RETURN v_ret_string;
   ELSE
      v_ret_string := 'A Valid ';
   END IF;

   /* Credit card number is valid now check for its type */

   IF SUBSTR (cc_number, 1, 1) = '4'          /* check if it is a Visa card */
   THEN
      IF LENGTH (cc_number) = 13 OR LENGTH (cc_number) = 16
      THEN
         v_ret_string := v_ret_string || 'Visa Credit Card Number.';
      END IF;
   ELSIF SUBSTR (cc_number, 1, 2) BETWEEN 51 AND 55  /* check if master card*/
   THEN
      IF LENGTH (cc_number) = 16
      THEN
         v_ret_string := v_ret_string || 'MasterCard Credit Card Number.';
      END IF;
   ELSIF SUBSTR (cc_number, 1, 2) = 34 OR SUBSTR (cc_number, 1, 2) = 37 /* check if amex card */
   THEN
      IF LENGTH (cc_number) = 15
      THEN
         v_ret_string :=
            v_ret_string || 'American Express Credit Card Number.';
      END IF;
   ELSE
      v_ret_string := v_ret_string || 'But unable to identify its type.';
   END IF;

   RETURN v_ret_string;
EXCEPTION
   WHEN OTHERS
   THEN
      RETURN 'Error...';
END validate_CC;

Testa

Ändra 4047xxxxxxxxxxxx-strängen nedan med ditt Visa-, MasterCard- eller Amex-kreditkortsnummer för att testa.

SET SERVEROUTPUT ON;

DECLARE
   RetVal      VARCHAR2 (100);
   CC_NUMBER   VARCHAR2 (100);
BEGIN
   CC_NUMBER := '4047xxxxxxxxxxxx';

   RetVal := VALIDATE_CC (CC_NUMBER);
   DBMS_OUTPUT.put_line (retval);
END;
/

Utdata

A Valid Visa Credit Card Number.
PL/SQL procedure successfully completed.

Obs! Testa noggrant innan du implementerar i din app.

Se även:

• Validera e-postadress med PL/SQL i Oracle