Hibernate Kryptering av databasen helt transparent för applikation

Om du slutar göra arbetet i applikationen kan du använda anpassade typer av Hibernate och det skulle inte lägga till så många ändringar i din kod.

Här är en krypterad sträng anpassad typ som jag har använt:

import org.hibernate.usertype.UserType
import org.apache.log4j.Logger

import java.sql.PreparedStatement
import java.sql.ResultSet
import java.sql.SQLException
import java.sql.Types

class EncryptedString implements UserType {

  // prefix category name with 'org.hibernate.type' to make logging of all types easier
  private final Logger _log = Logger.getLogger('org.hibernate.type.com.yourcompany.EncryptedString')

  Object nullSafeGet(ResultSet rs, String[] names, Object owner) throws SQLException {
    String value = rs.getString(names[0])

    if (!value) {
      _log.trace "returning null as column: $names[0]"
      return null
    }

    _log.trace "returning '$value' as column: $names[0]"
    return CryptoUtils.decrypt(value)
  }

  void nullSafeSet(PreparedStatement st, Object value, int index) throws SQLException {
    if (value) {
      String encrypted = CryptoUtils.encrypt(value.toString())
      _log.trace "binding '$encrypted' to parameter: $index"
      st.setString index, encrypted
    }
    else {
      _log.trace "binding null to parameter: $index"
      st.setNull(index, Types.VARCHAR)
    }
  }

  Class<String> returnedClass() { String }

  int[] sqlTypes() { [Types.VARCHAR] as int[] }

  Object assemble(Serializable cached, Object owner) { cached.toString() }

  Object deepCopy(Object value) { value.toString() }

  Serializable disassemble(Object value) { value.toString() }

  boolean equals(Object x, Object y) { x == y }

  int hashCode(Object x) { x.hashCode() }

  boolean isMutable() { true }

  Object replace(Object original, Object target, Object owner) { original }
}

och baserat på detta borde det vara enkelt att skapa liknande klasser för int, long, etc. För att använda det, lägg till typen i mappningsstängningen:

class MyDomainClass {

  String name
  String otherField

  static mapping = {
    name type: EncryptedString
    otherField type: EncryptedString
  }
}

Jag har utelämnat metoderna CryptoUtils.encrypt() och CryptoUtils.decrypt() eftersom det inte är Grails-specifikt. Vi använder AES, t.ex. "Cipher cipher =Cipher.getInstance('AES/CBC/PKCS5Padding')". Vad du än slutar med att använda, se till att det är en 2-vägs krypto, d.v.s. använd inte SHA-256.