Hitta och ersätt sträng inuti BLOB for Work eller Excel-fil

Microsoft Word- och Excel-filer är inte textfiler som du bara kan ersätta text på och som definitivt inte kommer att fungera med en BLOB . docx och xlsx filer är faktiskt zip-filer (prova att ändra filtillägget och packa upp för att se själv) som innehåller en XML-definition av dokumentet. Så du måste:

1. Packa upp filen
2. Konvertera filen som behöver ändras från en BLOB till en CLOB
3. Ändra innehållet i rätt XML-fil
4. Konvertera tillbaka filen till en BLOB från en CLOB
5. Lägg till den ändrade filen tillbaka i zip-filen

Jag har skrivit koden nedan som ett exempel på hur man ersätter en docx fil. För xlsx filer, finns varje Excel-ark i en annan XML-fil så du måste ändra koden något för att få den att fungera med båda filtyperna.

Koden använder APEX_ZIP paket som avsevärt förenklar arbetet med zip-filer och även gör exempelkoden lite tydligare om vad som pågår. Om du inte har APEX installerat måste du ta reda på hur du packar upp/omzippar filerna med de Oracle-paket du har.

DECLARE
    l_old_file       BLOB;
    l_new_file       BLOB;
    l_files          apex_zip.t_files;
    l_document       BLOB;
    l_clob           CLOB;
    l_dest_offsset   INTEGER;
    l_src_offsset    INTEGER;
    l_lang_context   INTEGER := DBMS_LOB.default_lang_ctx;
    l_warning        INTEGER;
BEGIN
    -- Get the blob you want to "correct"
    SELECT blob_content
      INTO l_old_file
      FROM apex_application_temp_files
     WHERE ROWNUM = 1;

    -- Get a list of all the file names contained within the zip
    l_files := apex_zip.get_files (l_old_file);

    -- Loop through all the files adding each one to the new zip
    FOR i IN l_files.FIRST .. l_files.LAST
    LOOP
        l_document := apex_zip.get_file_content (l_old_file, l_files (i));

        IF l_files (i) = 'word/document.xml'
        THEN
            -- if the file name is word/document.xml then make the changes to it
            
            DBMS_LOB.createTemporary (lob_loc => l_clob, cache => FALSE);

            l_dest_offsset := 1;
            l_src_offsset := 1;

            DBMS_LOB.converttoclob (dest_lob       => l_clob,
                                    src_blob       => l_document,
                                    amount         => DBMS_LOB.lobmaxsize,
                                    dest_offset    => l_dest_offsset,
                                    src_offset     => l_src_offsset,
                                    blob_csid      => DBMS_LOB.default_csid,
                                    lang_context   => l_lang_context,
                                    warning        => l_warning);

            --------------------
            -- This is where you would do any replacements
            --------------------
            l_clob := REPLACE (l_clob, 'www.google.co.uk', 'www.google.com');
            --------------------

            l_dest_offsset := 1;
            l_src_offsset := 1;

            DBMS_LOB.CONVERTTOBLOB (dest_lob       => l_document,
                                    src_clob       => l_clob,
                                    amount         => DBMS_LOB.lobmaxsize,
                                    dest_offset    => l_dest_offsset,
                                    src_offset     => l_src_offsset,
                                    blob_csid      => DBMS_LOB.default_csid,
                                    lang_context   => l_lang_context,
                                    warning        => l_warning);
        END IF;

        apex_zip.add_file (l_new_file, l_files (i), l_document);
    END LOOP;

    apex_zip.finish (l_new_file);
    --Do whatever you want with the "new" file here
END;