Gå igenom loopen för att hitta upprepade namn

Gör inte loopar inom loopar i PL/SQL för detta – använd SQL för att ge dig data redo att användas.

Först skapar vi din tabell med lite testdata (jag gissar på datatyper - du ersätter med din egen) :

create table product_master (
   product_no        varchar2(10)
 , product_holder    varchar2(10)
 , product_catalogue varchar2(10)
)
/

insert into product_master values ('1', 'SMITH', 'TEMP')
/
insert into product_master values ('2', 'SMITH', 'TEMP')
/
insert into product_master values ('3', 'HARRY', 'ARCH')
/
insert into product_master values ('4', 'TOM'  , 'DEPL')
/
commit
/

Vad vi vill skicka till mail_send procedur för varje product_holder är en samling (array) som innehåller product_no och product_catalogue . Så först en typ som innehåller dessa två element:

create type t_prod_cat_no as object (
   product_no        varchar2(10)
 , product_catalogue varchar2(10)
)
/

Och sedan en kapslad tabelltyp (samlingstyp) av den typen:

create type t_prod_cat_no_table as
   table of t_prod_cat_no
/

Proceduren mail_send bör sedan acceptera product_holder och samlingstypen:

create or replace procedure mail_send (
   p_parameter        in varchar2
 , p_product_holder   in varchar2
 , p_product_cats_nos in t_prod_cat_no_table
)
is
begin
   dbms_output.put_line('-- BEGIN '||p_parameter||' --');
   dbms_output.put_line('Dear '||p_product_holder);
   dbms_output.put_line('Your products are:');
   for i in 1..p_product_cats_nos.count loop
      dbms_output.put_line(
         'Catalogue: '||p_product_cats_nos(i).product_catalogue||
         ' - No: '||p_product_cats_nos(i).product_no
      );
   end loop;
end mail_send;
/

(Jag använder bara dbms_output för att simulera att bygga ett e-postmeddelande.)

Sedan kan du i SQL göra en group by product_holder och låt SQL generera samlingen som innehåller data:

begin
   for holder in (
      select pm.product_holder
           , cast(
                collect(
                   t_prod_cat_no(pm.product_no,pm.product_catalogue)
                   order by pm.product_catalogue
                          , pm.product_no
                ) as t_prod_cat_no_table
             ) product_cats_nos 
        from product_master pm
       group by pm.product_holder
       order by pm.product_holder
   ) loop
      mail_send(
         'PRODMASTER'
       , holder.product_holder
       , holder.product_cats_nos
      );
   end loop;
end;
/

Utdata från blocket ovan kommer att vara:

-- BEGIN PRODMASTER --
Dear HARRY
Your products are:
Catalogue: ARCH - No: 3
-- BEGIN PRODMASTER --
Dear SMITH
Your products are:
Catalogue: TEMP - No: 1
Catalogue: TEMP - No: 2
-- BEGIN PRODMASTER --
Dear TOM
Your products are:
Catalogue: DEPL - No: 4

Gör det i SQL med en GROUP BY ger dig allt i ett enda anrop från PL/SQL till SQL, vilket är mycket effektivare än det första anropet för att få den distinkta uppsättningen product_holder , loop över det och sedan ett anrop per product_holder för att få produkterna för varje hållare.

UPPDATERING:

Lade till order by till collect funktion i koden ovan för att visa att du har kontroll över ordningen som data fylls i i samlingen.