Konsolidera flera Oracle-utlösare. Någon prestationspåverkan?

Jag har nu benchmarkat den här situationen och jag kom till slutsatsen att det är en betydande prestandaförlust troligen på grund av PL/SQL-kontextväxlar när man lägger till 1 trigger. Förlusten är med faktor 8 i mitt benchmark. Att lägga till en andra "kompatibel" utlösare har dock ingen nämnvärd effekt längre. Med "kompatibel" menar jag att båda triggarna alltid utlöses vid samma händelse i valfri ordning.

Så jag drar slutsatsen att det sannolikt bara finns 1 SQL -> PL/SQL kontextväxel för alla utlösare

Här är riktmärket:

Skapa en tabell

-- A typical table with primary key, creation/modification user/date, and 
-- other data columns
CREATE TABLE test(
  id number(38)    not null, -- pk
  uc varchar2(400) not null, -- creation user
  dc date          not null, -- creation date
  um varchar2(400),          -- modification user
  dm date,                   -- modification date
  data number(38)
);

... och en sekvens

CREATE SEQUENCE s_test;

Ett typiskt triggerinställnings-ID, skapande/ändringsanvändare/datum

CREATE OR REPLACE TRIGGER t_test BEFORE INSERT OR UPDATE
  ON test
  FOR EACH ROW
BEGIN
  IF inserting THEN
    SELECT s_test.nextval INTO :new.id FROM dual;

    :new.uc := USER;
    :new.dc := SYSDATE;
    :new.um := NULL;
    :new.dm := NULL;
  END IF;
  IF updating THEN
    :new.um := USER;
    :new.dm := SYSDATE;
    :new.uc := :old.uc;
    :new.dc := :old.dc;
  END IF;
END t_test;

Infoga 1000, 10000, 100000 poster

declare
  procedure run (limit number) is
    t timestamp;
  begin
    t := systimestamp;

    insert into test (data)
    select level from dual connect by level < limit;

    dbms_output.put_line(to_char(systimestamp - t));

    rollback;
  end;
begin
  run(1000);
  run(10000);
  run(100000);
end;

Resultat

-- ------------------------------------
-- +000000000 00:00:00.086603000
-- +000000000 00:00:00.844333000
-- +000000000 00:00:08.429186000
-- ------------------------------------

En annan "kompatibel" trigger (exekveringsorder irrelevant)

CREATE OR REPLACE TRIGGER t_test_other BEFORE INSERT OR UPDATE
  ON test
  FOR EACH ROW
BEGIN
  :new.data := 42;
END t_test_other;

Resultat av ytterligare en körning av testskriptet

-- ------------------------------------
-- +000000000 00:00:00.088551000
-- +000000000 00:00:00.876028000
-- +000000000 00:00:08.731345000
-- ------------------------------------

Inaktivera utlösare

alter trigger t_test disable;
alter trigger t_test_other disable;

Kör ett lite annorlunda testskript

declare
  procedure run (limit number) is
    t timestamp;
  begin
    t := systimestamp;

    insert into test (id, uc, dc, data)
    select s_test.nextval, user, sysdate, level from dual 
    connect by level < limit;

    dbms_output.put_line(to_char(systimestamp - t));

    rollback;
  end;
begin
  run(1000);
  run(10000);
  run(100000);
end;

Resultat

-- ------------------------------------
-- +000000000 00:00:00.012712000
-- +000000000 00:00:00.104903000
-- +000000000 00:00:01.043984000
-- ------------------------------------