Oracle SQL Insert Trigger to Hash Password fungerar inte (problem med CHAR)

[TL;DR] Använd STANDARD_HASH( RTRIM( :new.PASSWORD ), 'SHA256' ) eftersom du vill skapa lösenordet på 'BruteForce' och inte 'BruteForce ' (etc.) utfylld med blanksteg till en längd av 64 tecken (vilket är vad som använder CHAR(64) skulle ge dig).

Om du inte vill använda ett salt (som du borde använda i denna dag och ålder) är det bara att högerklippa lösenordet för att bli av med det efterföljande blanktecken som CHAR datatyp har fyllt ut strängen med:

CREATE OR REPLACE TRIGGER client_hash_trigger
BEFORE INSERT ON client
FOR EACH ROW
BEGIN
  SELECT STANDARD_HASH( RTRIM( :new.PASSWORD ), 'SHA256' )
  INTO   :new.PASSWORD
  FROM   DUAL;
END;
/

Sedan:

CREATE TABLE client (
    id            NUMBER(10,0)
                  GENERATED ALWAYS AS IDENTITY
                  CONSTRAINT client__id__pk PRIMARY KEY,
    password      CHAR(64)
                  NOT NULL
);

INSERT INTO client (id, password) VALUES (DEFAULT, 'BruteForce');

Kommer att mata ut:

SELECT id, password FROM client;

Hashing och saltning

Anpassad från det här svaret

Om du också vill följa bästa praxis, bör du salta lösenordet innan du hash:

CREATE TABLE client (
    id            NUMBER(10,0)
                  GENERATED ALWAYS AS IDENTITY
                  CONSTRAINT client__id__pk PRIMARY KEY,
    password      CHAR(64)
                  NOT NULL,
    password_salt VARCHAR2(61)
                  NOT NULL
);

Då är din trigger:

CREATE TRIGGER client_hash_trigger
BEFORE INSERT OR UPDATE ON client
FOR EACH ROW
BEGIN
  IF :new.PASSWORD = :old.PASSWORD THEN
    -- Assume things haven't changed (The chances of a hash collision are vanishingly small).
    -- Make sure the old salt is not replaced if the password hash hasn't changed.
    :new.PASSWORD_SALT := :old.PASSWORD_SALT;
  ELSE
    -- Regenerate a new salt and hash the password.
    :new.PASSWORD_SALT := DBMS_RANDOM.STRING( 'P', FLOOR( DBMS_RANDOM.VALUE( 40, 61 ) ) );
    SELECT STANDARD_HASH ( :new.PASSWORD_SALT || RTRIM( :new.PASSWORD ), 'SHA256' )
    INTO   :new.PASSWORD
    FROM   DUAL;
  END IF;
END;
/

Och sedan:

INSERT INTO client (id, password) VALUES (DEFAULT, 'BruteForce');

Kan utdata:

SELECT * FROM client;

db<>fiol här