Tillhandahåller Oracle sättet att returnera flera delsträngar från en sträng/klumprad som har analyserats?

Något så här kanske:

CREATE OR REPLACE FUNCTION explode(longline varchar)
  RETURN sys.dbms_debug_vc2coll PIPELINED
IS  
  pos PLS_INTEGER;
  lastpos PLS_INTEGER;
  element varchar(2000);
BEGIN
   lastpos := 1;
   pos := instr(longline, ',');

   while pos > 0 loop
      element := substr(longline, lastpos, pos - lastpos);
      lastpos := pos + 1;
      pos := instr(longline, ',', lastpos);
      pipe row(element);
   end loop;

   if lastpos <= length(longline) then
      pipe row (substr(longline, lastpos));
   end if;

   RETURN;
END;  
/

Detta kan användas så här:

SQL> select * from table(explode('1,2,3'));

COLUMN_VALUE
---------------------------------------------
1
2
3
SQL>

Om du inte är på 11.x måste du själv definiera returtypen:

create type char_table as table of varchar(4000);

och ändra funktionsdeklarationen till:

CREATE OR REPLACE FUNCTION explode(longline varchar)
  RETURN char_table pipelined
.....