kan jag underhålla en Oracle-session från två oci-klienter?

Om du använder en 11g-databas kan du använda DBMS_XA paketför att tillåta en session att gå med i en transaktion som startades av den första sessionen. Som Tim Hall demonstrerar kan du starta en transaktion i en session, gå med i den transaktionen från en annan session och läsa de oengagerade ändringarna som gjorts i transaktionen. Tyvärr kommer det dock inte att hjälpa med sessionsvariabler (förutsatt att "sessionsvariabel" betyder paketvariabel som har sessionsomfång).

 
 Skapa paketet och tabellen:
 CREATE TABLE foo( col1 NUMBER );

create or replace package pkg_foo
as
  g_var number;
  procedure set_var( p_in number );
end;

create or replace package body pkg_foo
as
  procedure set_var( p_in number )
  as
  begin
    g_var := p_in;
  end;
end;
 
 I session 1 startar vi en global transaktion, ställer in paketvariabeln och infogar en rad i tabellen innan vi avbryter den globala transaktionen (vilket tillåter en annan session att återuppta den)
 SQL> ed
Wrote file afiedt.buf

  1  declare
  2    l_xid dbms_xa_xid := dbms_xa_xid( 1 );
  3    l_ret integer;
  4  begin
  5    l_ret := dbms_xa.xa_start( l_xid, dbms_xa.tmnoflags );
  6    pkg_foo.set_var(42);
  7    dbms_output.put_line( 'Set pkg_foo.g_var to ' || pkg_foo.g_var );
  8    insert into foo values( 42 );
  9    l_ret := dbms_xa.xa_end( l_xid, dbms_xa.tmsuspend );
 10* end;
SQL> /
Set pkg_foo.g_var to 42

PL/SQL procedure successfully completed.
 
 I session 2 återupptar vi den globala transaktionen, läser från tabellen, läser sessionsvariabeln och avslutar den globala transaktionen. Observera att frågan mot tabellen ser raden vi infogade men paketvariabeländringen är inte synlig.
 SQL> ed
Wrote file afiedt.buf

  1  declare
  2    l_xid dbms_xa_xid := dbms_xa_xid( 1 );
  3    l_ret integer;
  4    l_col1 integer;
  5  begin
  6    l_ret := dbms_xa.xa_start( l_xid, dbms_xa.tmresume );
  7    dbms_output.put_line( 'Read pkg_foo.g_var as ' || pkg_foo.g_var );
  8    select col1 into l_col1 from foo;
  9    dbms_output.put_line( 'Read COL1 from FOO as ' || l_col1 );
 10    l_ret := dbms_xa.xa_end( l_xid, dbms_xa.tmsuccess );
 11* end;
SQL> /
Read pkg_foo.g_var as
Read COL1 from FOO as 42

PL/SQL procedure successfully completed.
 
 För att dela sessionstillstånd mellan sessionerna, skulle det vara möjligt att använda en global applikationskontext
 istället för att använda paketvariabler? Du kan kombinera det med DBMS_XA paket om du vill läsa både databastabeller och sessionstillstånd.
 
 Skapa sammanhanget och paketet med getter och setter
 CREATE CONTEXT my_context
  USING pkg_foo
  ACCESSED GLOBALLY;

create or replace package pkg_foo
as
  procedure set_var( p_session_id in number,
                     p_in         in number );
  function get_var( p_session_id in number )
    return number;
end;

create or replace package body pkg_foo
as
  procedure set_var( p_session_id in number,
                     p_in         in number )
  as
  begin
    dbms_session.set_identifier( p_session_id );
    dbms_session.set_context( 'MY_CONTEXT', 'G_VAR', p_in, null, p_session_id );
  end;
  function get_var( p_session_id in number )
    return number
  is
  begin
    dbms_session.set_identifier( p_session_id );
    return sys_context('MY_CONTEXT', 'G_VAR');
  end;
end;
 
 I session 1 ställer du in värdet för kontextvariabeln G_VAR till 47 för session 12345
 begin
  pkg_foo.set_var( 12345, 47 );
end;
 
 Nu kan session 2 läsa värdet från sammanhanget
   1* select pkg_foo.get_var( 12345 ) from dual
SQL> /

PKG_FOO.GET_VAR(12345)
----------------------
                    47