Oracle PL/SQL:Exportera data från en tabell till CSV

Lär dig hur du använder UTL_FILE paket för att exportera data från en tabell till CSV-filen i Oracle PL/SQL.

I Oracle, paketet UTL_FILE innehåller många procedurer och funktioner för att skriva en textfil. Nedan finns syntaxdetaljer och nödvändiga steg för att skriva en fil:

Syntax och steg för att skriva en fil med UTL_FILE

-- Declare a variable to store file type
n_file UTL_FILE.FILE_TYPE;
-- Open the file in Begin section, it will open the file and return the file handle into the variable n_file
n_file := UTL_FILE.FOPEN('DIR_OBJ', 'YourCSVFileName.csv', 'w', 4000);
-- Write a single or multiple lines
UTL_FILE.PUT_LINE(n_file, 'abc, xyz, xxx');
-- Close the file
UTL_FILE.FCLOSE(n_file);

Grundläggande exempel

Declare
   n_file Utl_File.File_Type;
Begin
   -- The directory object MY_DIR must be exist or create a new one
   n_file := Utl_File.Fopen('MY_DIR', 'myfile.csv', 'w', '4000');

   Utl_File.Put_Line(n_file, 'First line.');
   Utl_File.Put_Line(n_file, 'Second line.');
   Utl_File.Put_Line(n_file, 'Third line.');

   Utl_File.Fclose(n_file);
End;

Som jag nämnde i exemplet ovan, katalogobjektet MY_DIR måste finnas. Katalogobjektet i Oracle är en referens till den fysiska katalogen på servern. Följande är ett exempel på att skapa ett katalogobjekt i Oracle:

-- Windows example
CREATE OR REPLACE DIRECTORY CSVDIR AS 'd:\oracle\csvfiles';
-- Linux example
CREATE OR REPLACE DIRECTORY CSVDIR AS '/usr1/oracle/csvfiles';

För att lära dig mer om katalogobjektet i Oracle, kolla den här länken.

Exportera data från en tabell till CSV i Oracle-exempel

Följande är ett exempel på en lagrad procedur i Oracle, som exporterar data från EMP-tabellen till en CSV-fil:

Create Or Replace Procedure exp_emp_data Is

    n_file     utl_file.file_type;
    v_string   Varchar2(4000);
   
  -- get the data using cursor 
  Cursor c_emp Is
    Select
        empno,
        ename,
        deptno,
        sal,
        comm
    From
        emp;

Begin
    n_file := utl_file.fopen('CSVDIR', 'empdata.csv', 'w', 4000);

-- if you do not want heading then remove below two lines
    v_string := 'Emp Code, Emp Name, Dept, Salary, Commission';
    utl_file.put_line(n_file, v_string);
    
    -- open the cursor and concatenate fields using comma
    For cur In c_emp Loop
        v_string := cur.empno
                    || ','
                    || cur.ename
                    || ','
                    || cur.deptno
                    || ','
                    || cur.sal
                    || ','
                    || cur.comm;
        
        -- write each row
        utl_file.put_line(n_file, v_string);
    End Loop;
    
    -- close the file
    utl_file.fclose(n_file);
Exception
    When Others Then
        -- on error, close the file if open
        If utl_file.is_open(n_file) Then
            utl_file.fclose(n_file);
        End If;
End;

Nu har din lagrade procedur skapats, kör den för att exportera data:

Begin
    exp_emp_data;
End;

Relaterade självstudier:

• Verktyg:Generera PL/SQL-procedur för att exportera data från en tabell