Hur får man en fil från BLOB i Oracle?

I den här handledningen kommer du att lära dig hur du hämtar en fil från BLOB-kolumnen i Oracle. För att ge ett exempel har jag skapat en tabell EXT_FILES i Oracle och följande är tabellens struktur.

CREATE TABLE EXT_FILES
(
FILE_NAME VARCHAR2(1000 BYTE),
FILE_CONTENT BLOB
)
/

Infoga data i tabellen ovan. Om du inte vet hur man infogar en fil i BLOB-kolumnen, kolla följande artikel Hur man infogar en fil i Oracle Table BLOB-kolumn?

Du måste ha ett Oracle-katalogobjekt skapat i ditt schema för att få filerna från BLOB-kolumnen till disken. För att skapa en katalog i Oracle ge följande kommando.

CREATE OR REPLACE DIRECTORY IMGDIR AS 'C:\TEMP\IMAGES';

Nedan är exemplet med Oracle Stored Procedure, som hämtar posterna från tabellen EXT_FILES (som innehåller BLOB-data) med hjälp av en markör och sedan extraherar filerna en efter en till den angivna katalogen.

Oracle Stored Procedure Exempel för att hämta filen från BLOB Column i Oracle

CREATE OR REPLACE PROCEDURE get_files_from_blob
IS
l_file UTL_FILE.file_type;
l_buffer RAW (32767);
l_amount BINARY_INTEGER := 32767;
l_pos INTEGER := 1;
l_blob_len INTEGER;
l_blob BLOB;
l_filename ext_files.file_name%TYPE;
/* cursor to get the records from the table */
CURSOR c_files
IS
SELECT file_name, file_content FROM ext_files;
BEGIN
OPEN c_files;

LOOP

FETCH c_files
INTO l_filename, l_blob;

EXIT WHEN c_files%NOTFOUND;

l_blob_len := DBMS_LOB.getlength (l_blob);

/* Change the directory name (IMGDIR) to your Oracle directory object name*/
l_file :=
UTL_FILE.fopen ('IMGDIR',
l_filename,
'wb',
32767);
l_pos := 1;

WHILE l_pos < l_blob_len
LOOP
DBMS_LOB.read (l_blob,
l_amount,
l_pos,
l_buffer);
UTL_FILE.put_raw (l_file, l_buffer, TRUE);
l_pos := l_pos + l_amount;
END LOOP;

UTL_FILE.fclose (l_file);
END LOOP;

CLOSE c_files;
EXCEPTION
WHEN OTHERS
THEN
IF UTL_FILE.is_open (l_file)
THEN
UTL_FILE.fclose (l_file);
END IF;

RAISE;
END;

Testa

BEGIN
get_files_from_blob;
END;
/

Utdata

PL/SQL procedure successfully completed.

Du kan nu kontrollera platsen för IMGDIR-katalogobjektet för de extraherade filerna.

Se även:

• Extrahera BLOB-data från Oracle Table med hjälp av Toad