SQL-sats från DML Trigger

Som Jonas säger, Profiler är ditt bästa alternativ (och enda alternativet för SELECT-frågor). För INSERT, UPDATE, DELETEs kan det närmaste du kan komma utan Profiler vara att titta på indatabufferten via DBCC INPUTBUFFER(@@SPID) . Detta fungerar bara för ad-hoc-språkhändelser, inte RPC-anrop, och kommer bara att visa dig de första 256 tecknen i SQL-satsen (beroende på version tror jag). Något exempelkod, (kör som dbo):

CREATE TABLE TBL (a int, b varchar(50))
go

INSERT INTO TBL SELECT 1,'hello'
INSERT INTO TBL SELECT 2,'goodbye'
go

GRANT SELECT, UPDATE ON TBL TO guest
go

CREATE TABLE AUDIT (    audittime datetime default(getdate())
                    ,   targettable sysname
                    ,   loginname sysname
                    ,   spid int
                    ,   sqltext nvarchar(max))
go

CREATE TRIGGER TR_TBL ON TBL FOR INSERT, UPDATE, DELETE
AS BEGIN
    CREATE TABLE #DBCC (EventType varchar(50), Parameters varchar(50), EventInfo nvarchar(max))

    INSERT INTO #DBCC
    EXEC ('DBCC INPUTBUFFER(@@SPID)')

    INSERT INTO AUDIT (targettable, loginname, spid, sqltext)
        SELECT  targettable =   'TBL'
        ,       suser       =   suser_name()
        ,       spid        =   @@SPID
        ,       sqltext     =   EventInfo 
        FROM #DBCC
END
GO

/* Test the Audit Trigger (can be run as guest) */
UPDATE TBL SET a = 3 WHERE a = 2