Dela upp avgränsade värden i en SQL-kolumn i flera rader

Om du använder SQL Server 2016+

Du kan använda den nya STRING_SPLIT funktion, som jag har bloggat om här, och Brent Ozar har bloggat om här.

SELECT s.[message-id], f.value
  FROM dbo.SourceData AS s
  CROSS APPLY STRING_SPLIT(s.[recipient-address], ';') as f;

Om du fortfarande har en version före SQL Server 2016

Skapa en delad funktion. Det här är bara ett av många exempel där ute:

CREATE FUNCTION dbo.SplitStrings
(
    @List       NVARCHAR(MAX),
    @Delimiter  NVARCHAR(255)
)
RETURNS TABLE
AS
    RETURN (SELECT Number = ROW_NUMBER() OVER (ORDER BY Number),
        Item FROM (SELECT Number, Item = LTRIM(RTRIM(SUBSTRING(@List, Number, 
        CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)))
    FROM (SELECT ROW_NUMBER() OVER (ORDER BY s1.[object_id])
        FROM sys.all_objects AS s1 CROSS APPLY sys.all_objects) AS n(Number)
    WHERE Number <= CONVERT(INT, LEN(@List))
        AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
    ) AS y);
GO

Jag har diskuterat några andra här, här, och ett bättre tillvägagångssätt än att splittra i första hand här.

Nu kan du extrapolera helt enkelt genom att:

SELECT s.[message-id], f.Item
  FROM dbo.SourceData AS s
  CROSS APPLY dbo.SplitStrings(s.[recipient-address], ';') as f;

Jag föreslår också att du inte sätter streck i kolumnnamn. Det betyder att du alltid måste sätta dem inom [square brackets] .